Grabbing a PolyPlanarProj from a selected face

[ron-hiler]

Hey guys,

I wrote this script in MEL to assign a planar projection to each selected face (or to convert a selected object to it's faces and then assign the projections to them), as well as a material. The script also adjusts the ImageCenterX, ImageCenterY, ImageScaleU, ImageScaleV, and RotationAngle of the planar projection. The texutre used in the material is a texture atlas filled with 31 textures that all tile together. The idea is to assign a random tile to each face of an object.

Okay, this all works great except for one thing. Every now and again, the tile image ends up upside down or sideways compared to the faces adjacent, and therefore no longer tiles properly (probably becuase of the vertex order or whatever). No problem, I thought, I can just write a script to flip a selected face 90 degrees with the push of a button until it is the right direction.

This turned out to be much much harder than the original script! The problem I'm having is I can't get from "selected face" to "PolyPlanarProj" in order to read out the current RotationAngle value, which I need before I can add 90 degrees to it. This is the script I've been playing with:

string $select[] = `ls -sl`;
//grab a list of the selected faces
string $faceList[] = `filterExpand -sm 34`;
for($i=0; $i<size($faceList); $i++)
    {
    select $faceList[$i];
    $angle = `polyPlanarProjection -query -ra`;
    print ($angle);
    $angle += 90;
    $angle %= 360;
    print ($angle);
    polyPlanarProjection -edit -ra $angle;
    //flip the scales (not done yet)
//    setAttr ($result[0] + ".imageScaleU") 0.125;  //TODO
//    setAttr ($result[0] + ".imageScaleV") 0.250;  //TODO
    }
//restore the original selection
select -r $select;

Of course that is not working, because (I guess?) polyPlanarProjection isn't associated with a face, it's associated with the parent object. So the query is just (silently) failing.

Anyone have any advice? I'm not super fluent in MEL, so there's probaby an obvious solution I'm missing

[nowayfra]

The polyPlanarProj node must be associated with component indices in some way (object sets would be an other way to store the componets, but ther arent any new after projection), otherwise multiple projections per shape wouldnt work. That the node reference does not list an attribute to read out the indices does not mean such an attribute does not exist. The reference tends to be a bit stingy with information but in such cases you always can set up a little test object, for example an 1x2 poly plane with a projection node assigned to each face and export the mesh into a MayaAscii file. Then have a look into the code and see how the projection nodes get ther indices assigned.

[ron-hiler]

Thanks nowafra, that's a great idea, thanks for the suggestions. I did that, and then did a search in the doc for polyPlanarProj

createNode polyPlanarProj -n "polyPlanarProj1";
    setAttr ".uopa" yes;
    setAttr ".ics" -type "componentList" 1 "f[1]";
    setAttr ".ix" -type "matrix" 2.2204460492503131e-016 1 0 0 -1 2.2204460492503131e-016 0 0
         0 0 1 0 6.9527489073474042e-017 0.6762915992221048 0 1;
    setAttr ".ws" yes;
    setAttr ".pc" -type "double3" 1.2503860662698579e-016 0.92629158496856689 -1.9572297667976512e-017 ;
    setAttr ".ro" -type "double3" -89.999999999999986 -6.3611093629270304e-015 89.999999999999972 ;
    setAttr ".ps" -type "double2" 0.5 1 ;
    setAttr ".cam" -type "matrix" 1 0 0 0 0 1 0 0 0 0 1 0 0 0 0 1;
createNode polyPlanarProj -n "polyPlanarProj2";
    setAttr ".uopa" yes;
    setAttr ".ics" -type "componentList" 1 "f[0]";
    setAttr ".ix" -type "matrix" 2.2204460492503131e-016 1 0 0 -1 2.2204460492503131e-016 0 0
         0 0 1 0 6.9527489073474042e-017 0.6762915992221048 0 1;
    setAttr ".ws" yes;
    setAttr ".pc" -type "double3" 1.4016304164470137e-017 0.42629158496856689 3.5938853563281315e-017 ;
    setAttr ".ro" -type "double3" -89.999999999999986 -6.3611093629270304e-015 89.999999999999972 ;
    setAttr ".ps" -type "double2" 0.5 1 ;
    setAttr ".cam" -type "matrix" 1 0 0 0 0 1 0 0 0 0 1 0 0 0 0 1;

And then toward the end of the document there were these lines:

connectAttr "polyPlanarProj2.out" "pPlaneShape1.i";
connectAttr "polyPlane1.out" "polyPlanarProj1.ip";
connectAttr "pPlaneShape1.wm" "polyPlanarProj1.mp";
connectAttr "polyPlanarProj1.out" "polyPlanarProj2.ip";
connectAttr "pPlaneShape1.wm" "polyPlanarProj2.mp";

So, how to use that information? This is interesting
    setAttr ".ics" -type "componentList" 1 "f[1]";
We seem to have a face reference right in the node data, in the ics attribute (whateve the hell that is, hehe. It's not listed in the docs, so hopefully I can query it).

So I guess I could loop through all the polyPlanarPojections on an object and use getAttr polyPlanarProj[$i].ics to grab that face index, and check that against the selected faces, if it's a match, I modify its values. Something like that?

[nowayfra]

yes, exactly

[ron-hiler]

Whew, I did it. That was, by far, the most complicated MEL script I've written to date Not that I've written a lot of them. I spent a lot of time trying to figure out where to find the nodes. How to get the parent object of a selected face. From there, how to grab the projections, and so on. But I did learn quite a bit in the proces.

Anyway, in case anyone runs into anything similar, I'll post the code I came up with. There is a lot of looping going on, but it seems fast enough for what I'm doing. If you guys have suggestions on optimizations, feel free to let me know.

string $select[] = `ls -sl`;
//grab a list of the selected faces
string $faceList[] = `filterExpand -sm 34`;
//for each face, loop through the object and find the assoicated planar projection
//since the planar projection is a history node, this won't work after history is cleared!
for($i=0; $i<size($faceList); $i++)
    {
    select $faceList[$i];
    //grab the object that is the parent of this face
    string $object[] = listRelatives("-p", `listRelatives -p $faceList[$i]`);
    //get the polyPlanarProj history nodes
    string $history[] = `listHistory $object[0]`;
    for($j=0; $j<size($history); $j++)
        {
        if (size(`match "polyPlanarProj*" $history[$j]`) >0)
            {
            string $projectionAttrICS[] = `listAttr -sn -st ics $history[$j]`;
            for($k=0; $k<size($projectionAttrICS); $k++)
                {
                $attributeName = $history[$j] + "." + $projectionAttrICS[$k];
                string $result[] = `getAttr $attributeName`;
                //we finally have the face of each projection, test it against the current face
                if (endsWith($faceList[$i], $result[0]) == 1)
                    {
                    //match! This is the right projection to rotate
                    //add 90 degrees to the rotation
                    float $angle = `getAttr($history[$j] + ".ra")`;
                    $angle += 90;
                    $angle %= 360;
                    setAttr($history[$j] + ".ra") $angle;
                    //swap the image scales
                    float $oldScaleU = `getAttr($history[$j] + ".imageScaleU")`;
                    float $oldScaleV = `getAttr($history[$j] + ".imageScaleV")`;
                    setAttr($history[$j] + ".imageScaleU") $oldScaleV;
                    setAttr($history[$j] + ".imageScaleV") $oldScaleU;
                    }
                }
            }
        }
    }
//restore the original selection
select -r $select;

[joojaa]

That the node reference does not list an attribute to read out the indices does not mean such an attribute does not exist.

FYI its in the node reference all right. Its just that maya chooses only to show each levels data* but not inherited values. So if you take poly planar projection reference you see, thet it inherits from:

polyPlanarProj - polyModifierWorld - polyModifier - polyBase - dependNode

You need to read all those entries. Now the data is under polyModifier, and most polygon manipulating tools inherit form this abstract node. Heres what the node reference says about this attribute.

Name: inputComponents (ics)
type: componentList
Defaults: NULL
Attribs: output, input, connectable, storable
Description: Input components that this node is to work on.

*this sucks if you want to find relevant data quickly

Some pointers for the script.

dont do the matching the node matching that way use:

$allPlanarProjectionNodes =`ls -type polyPlanarProj (listHistory($object[0]))`;

it will also work if somebody renamed the node. same kind of stuff for checking match. All in all you should be able to lill 50% of your lines and meake it easier to manage.

[nowayfra]

Here is a approach to avoid the heavy per face looping, it just loops a first time and puts the names of projection nodes into an array. This does not work if faces of multiple meshes are selected or if meshes have additional uv sets (in this case you would have to sort out the proj nodes by checking their ".uvs" attribute).

string $projNodeList[] = {}; //will hold the names of projection nodes for each face index
if(! size $projNodeList){
    string $mesh[] = ls -o -dag -long -sl; //get the transform and shape from component selections
    string $projs[] = listConnections -s 0 -d 1 -et 1 -t "polyPlanarProj" $mesh[0]; // get connected polyPlanarProj nodes
    string $tmp[];
    for($node in $projs){
        string $indices[] = getAttr ($node + ".ics");
        for($idx in $indices){
            int $numToken = tokenize $idx "[:]" $tmp; // extract the face indices from the string value
            for($i= int($tmp[1]);$i<= int($tmp[$numToken - 1]);$i++) //a loop in case the string value looked like f[0:3]
                $projNodeList[$i] = $node;
        };
    };
};

string $faces[] = filterExpand -sm 34 (ls( "-long", "-sl"));
for($face in $faces){
    string $tmp[];
    tokenize $face "[]" $tmp;
    string $proj = $projNodeList[int($tmp[1])];
    print($face + ": " + $proj + "\n");
};

[nowayfra]

btw joojaa whats the "insert/edit code" mode you use for maya script code? Never found the appropriate one so far.

[joojaa]

There isnt one. Bash forms the best one except that it doenst understand maya comments. TCL is next best but if its comment intensive i use c.

It wouldnt e much work to change the bash mode tough

PS: nowayfra by the way you dont need to tokenize you can use ls to expand indiices even if they are strings so;

ls -fl pPlane2.f[57:58] -> pPlane2.f[57] pPlane2.f[58]

now if you have an array of names ls handles them too:
string $arr[]={"pPlane2.f[57:58]","pPlane2.f[53:54]"};
ls -fl $arr;
-> pPlane2.f[57] pPlane2.f[58] pPlane2.f[53] pPlane2.f[54]

mayas even kind enough to handle duplicates. So you can just skip the entire inner for loop and you get the multi node function for free.

[nowayfra]

i know the -flatten flag, but i needed to get the index of the faces as 'pure int', so the remaining string salad had to be removed. so still the 4 lines

        for($idx in $indices){
            int $numToken = tokenize $idx "[:]" $tmp;
            for($i= int($tmp[1]);$i<= int($tmp[$numToken - 1]);$i++)
                $projNodeList[$i] = $node;

have to be beaten to get the polyPlanarProj node names according to their stored face indices into their corresponding slot in the $projNodeList[] array...

[ron-hiler]

Thanks a bunch for the optimization suggestions, guys. I'll work on incorporating them into the script today. Hopefully it should be fairly straightforward and I won't have any issues.

If there was a reputation system on this board, I'd +1 both of you. Really, thanks a lot, you helped me get through a tough spot. Now I can get my level textured much more efficiently!

[joojaa]

but i needed to get the index of the faces as 'pure int', so the remaining string salad had to be removed.

really. What if i told you that you dont need the index at all? Just glue the parent nodes name on the string then measure the length of the flat fo your glued string then length of the flat selection string, then length flattened of the combined array. If the sum is not len glued sel then you have a hit. Because you can feed umcompressed entities you can do a lot less operations.

Now this alaso resolves many different meshes selections.

[nowayfra]

Code please, sounds a bit vague.

[joojaa]

Unfortunately i have no maya at hand oh sorry somebody graciously let me ssh in on machine with maya so no worries i have a console to test on.

{
    string $projNodes[] = `ls -type polyPlanarProj (listHistory())`;
    for ($proj in $projNodes){
        string $sel[] = `ls -sl`;
        $len = size($sel);
        $shap = `ls -dag -shapes (listHistory("-f",1,$proj))`;
        $ics = `getAttr ($proj + ".ics")`;
        string $data[];
        for ($i=0;$i<size($ics);$i++) {
            $data[$i] = $shap[0]+"."+$ics[$i];
        }
        select -d $data;
        if (size(`ls -sl`) != $len){
            print("--- " + $proj + " collides rotate the bugger --\n");
            select -r $sel;
        }
    }
};

Very hard to say if it works well or not. I did find a maya to test this on but the maya i have only a text connection to. Anyway brief testing and i can conclude that it can in fact use as many selections and different objects. As long as you dont have some really magic connections going on.*

Anyway you can speed this up a bit by not blasting the global selection, but i dont have the time nor inclination to do so. Besides using maya without a gui is painfull enough.

• ok there is a limitation going on in that it can report rotates many times if the slections go back and forth much.

O(N*log(M)Log(M)) versus O(NM*O)

PS: this would be infinitely more elagant and fatster to do in python could be O(N)

[nowayfra]

Interesting approach... this should work if you declare $data as empty array.

string $data[] = {};

PS: i think it will fail if the size of the selection list after deselecting is the same as before (f[0:2] -> f[0:1]), so better modify the selection queries with the "-flatten" flag to get te full component list:

$sel[] = `ls -fl -sl`;

and

if (size(`ls -fl -sl`) != $len)

[joojaa]

Yeah,

anyway this kind fo code could work for other tools too imagine picking a face on model and then getti8ng first modifer in history thet affects the face. So selecting top face whit a tool fo shortcut form keyboard would for example switch you to a extrude nodes tool... etc.