Time taken to run custom script increases by 50-75% each time it's run

[andy-hosking]

Hi,
I have been working on a script which creates a scene of boxes from a database of xyz translate rotate scale values. It also takes an image library and textures each face of the cubes. This all works great but can create large scenes and now needs optimising.

THE PROBLEM:
The first line of the script creates a new scene.
However, if you run the script without opening Maya from scratch it takes around 50-75% longer.
I have to restart Maya even when working on a small simple scene.

I've tried "clearCache;" but that didn't help. I'm now out of ideas.
Can anyone help?
Thanks in advance for any ideas!
Andy

[thnkr]

is the undo queue on?

[andy-hosking]

Hi Michiel,
My undo queue is ON. It's set to finite with a size of 50.
However, turning it off doesn't seem to help at all.

[joojaa]

My undo queue is ON. It's set to finite with a size of 50.

yes but see one script is ONE CHUNK of undo.

So if your script odes 10,000 boxes then the undo needs to fill in 10,000 box creations into the undo stack. Now once your undo grows in size it gets slower and slower because your essentially leaking memory. So you are actually doinga unusually lage one step undo.

You should be actually looking at particle instancing.

[andy-hosking]

Thanks Joojaa.
When I turn off my undo queue it makes no difference so I'm guessing undo memory isn't the problem.
My first line is "file -f -new;" but it doesn't seem to totally refresh maya.

Eg. It also doesn't refresh UV Placement nodes that have changed from repeating in U only to repeating in V only, it instead repeats in U and V. I'm guessing this is more proof that I need to find some other way of re-initialising maya ... or maybe to stop being lazy and just restart maya manually each time. >

I'm trying to get this fool proof for when clients are using it without my assistance.

[joojaa]

but it doesn't seem to totally refresh maya.

well not everything in maya is cleared on file new all that youve loaded in the gui still is there. The mel environment for one stays intact.

Your not using big global arrays perchance

However, if you run the script without opening Maya from scratch it takes around 50-75% longer.

How much memory are you using? and how much do you have to begin with.

[joojaa]

oh ps any chance we can see the script. its awfully lot easier to debug stuff if you can see what it ate,

[andy-hosking]

How much memory are you using? and how much do you have to begin with.

My task manger says maya is using 255,000k when the script is running. Is that what you meant?

Your not using big global arrays perchance

As you can see below I'm not using any global arrays. I hardly even know what that means.

oh ps any chance we can see the script. its awfully lot easier to debug stuff if you can see what it ate,

Ok, here's a very small snippet of the kind of scripts im working with. They're produced automatically from a csv file of positional data.

//Get the start time
$startTime = timerX;
print $startTime;

//Set up the file
file -f -new; upAxis -ax z; currentUnit -linear "in";
polyCube -w 1 -h 1 -d 1 -name BlockAttributes -createUVs 2; rotate 0 0 90;
makeIdentity -apply true -t 1 -r 1 -s 1 -n 0;
rename |BlockAttributes|BlockAttributesShape "Block" ;
select -r BlockAttributes.f[1]; ConvertSelectionToUVs; polyRotateUVs 180;
select -r BlockAttributes.f[5]; ConvertSelectionToUVs; polyRotateUVs 90;
select -r BlockAttributes.f[4]; ConvertSelectionToUVs; polyRotateUVs -90;
select -r BlockAttributes.f[0]; ConvertSelectionToUVs; polyRotateUVs 90; polyFlipUV -flipType 0; polyFlipUV -flipType 1;
select -r BlockAttributes.f[2]; ConvertSelectionToUVs; polyRotateUVs -90;
select BlockAttributes; DeleteHistory;

//Create The Fixture Shaders
shadingNode -asShader lambert -name "Fixture_Base";
sets -renderable true -noSurfaceShader true -empty -name "Fixture_BaseGroup";
connectAttr -f Fixture_Base.outColor Fixture_BaseGroup.surfaceShader;
setAttr "Fixture_Base.color" -type double3 0.1 0.1 0.1 ;

shadingNode -asShader lambert -name "Fixture_Back";
sets -renderable true -noSurfaceShader true -empty -name "Fixture_BackGroup";
connectAttr -f Fixture_Back.outColor Fixture_BackGroup.surfaceShader;
shadingNode -asTexture file -name Fixture_Back_Image;
connectAttr -force Fixture_Back_Image.outColor Fixture_Back.color;
setAttr Fixture_Back_Image.ftn -type "string" "textures/shelving-holes.jpg" "image";
shadingNode -asUtility place2dTexture -name Fixture_Back_Placement;
connectAttr -force Fixture_Back_Placement.outUV Fixture_Back_Image.uvCoord;
connectAttr -force Fixture_Back_Placement.repeatUV Fixture_Back_Image.repeatUV;
setAttr "Fixture_Back_Placement.repeatU" 40; setAttr "Fixture_Back_Placement.repeatV" 60;

shadingNode -asShader lambert -name "Fixture_Shelf";
sets -renderable true -noSurfaceShader true -empty -name "Fixture_ShelfGroup";
connectAttr -f Fixture_Shelf.outColor Fixture_ShelfGroup.surfaceShader;
setAttr "Fixture_Shelf.color" -type double3 0.85 0.85 0.85 ;

//Product Number -Fix_70701016_PLN_Section4_7222
//Product Type -FIXTURE
select -r BlockAttributes ;
duplicate -rr -renameChildren BlockAttributes; scale -r 48 22 0.001; rotate -r 0 0 0; move -r  24 -11 0.0005;
rename |BlockAttributes1|Block1 "Fix_70701016_PLN_Section4_7222" ;
rename |BlockAttributes1 "Fix_70701016_PLN_Section4_7222_ATR" ;
select -r Fix_70701016_PLN_Section4_7222_ATR ;
makeIdentity -apply true -t 1 -r 1 -s 1 -n 0;
move 0 0 0 Fix_70701016_PLN_Section4_7222_ATR.scalePivot Fix_70701016_PLN_Section4_7222_ATR.rotatePivot ;
defaultNavigation -source Fixture_Shelf -destination |Fix_70701016_PLN_Section4_7222_ATR|Fix_70701016_PLN_Section4_7222.instObjGroups[0] -connectToExisting;
select -r Fix_70701016_PLN_Section4_7222;
rotate -r -os 0 0 0;
move -r 2883.053563 1559.536442 0;

//Product Number -Base_0_7223
//Product Type -BASE
select -r BlockAttributes ;
duplicate -rr -renameChildren BlockAttributes; scale -r 48 18 4.75; rotate -r 0 0 0; move -r  24 -6 2.375;
rename |BlockAttributes1|Block1 "Base_0_7223" ;
rename |BlockAttributes1 "Base_0_7223_ATR" ;
select -r Base_0_7223_ATR ;
makeIdentity -apply true -t 1 -r 1 -s 1 -n 0;
move 0 0 0 Base_0_7223_ATR.scalePivot Base_0_7223_ATR.rotatePivot ;
defaultNavigation -source Fixture_Base -destination |Base_0_7223_ATR|Base_0_7223.instObjGroups[0] -connectToExisting;
select -r Base_0_7223;
rotate -r -os 0 0 0;
move -r 2883.053563 1559.536442 0;
select -r Base_0_7223 ;
select -tgl Fix_70701016_PLN_Section4_7222 ;
parent;

//Ending
select -r BlockAttributes ;
doDelete;
setNamedPanelLayout "Single Perspective View";
camera -name Camera_1; move 0 0 70; rotate 45 0 0; scale 30 30 30;
lookThru Camera_1;
$current_panel = getPanel -wf;
$panel_type = getPanel -to $current\_panel;
if ($panel_type == "modelPanel")
modelEditor -e -da "wireframe" $current_panel;
select -cl;
viewFit;
$totalTime = timerX -startTime $startTime;
print ("Total Time: "+$totalTime+"\n");

[joojaa]

err why the hell are you bothering us with fractional seconds? if that indeed is your code then yes the aswer is clear. First time file -f -new is not doing anything next time it is. If you take out the file new form the equation its actually very consistently same speed every time.

My task manger says maya is using 255,000k when the script is running. Is that what you meant?

yes, kindof that half of the question. In it self its not much but if your computer is running low on memory even 1k can be much. So inorder to do something with this i need to see it in perspective with how much you have to begin with.

currentUnit -linear "in";

Ugh, are you perhaps feeling suicidial? NEVER EVER SET THE MAYA DEFAULT UNIT. Mostly because the onlt thing you will get is lots of problems and maya doesnt respect it anyhow. So no point in setting it. Yes yes you will cry fowl here but truly maya has no units, end of discussion. If you want to read the long explanation serach the beards, not feeling up to it right now.

In any case you code could be so much shorter if youd write it properly.

[joojaa]

Ok for starters you could do this:

//Set up the file
upAxis -ax z;
currentUnit -linear "in";
polyCube -w 1 -h 1 -d 1 -ax -1 0 0 -ch 0
         -name BlockAttributes -createUVs 2;
rename |BlockAttributes|BlockAttributesShape "Block" ;
polyEditUV -pu 0.5 -pv 0.5 -a 180 BlockAttributes.map[4:7];
polyEditUV -pu 0.5 -pv 0.5 -a  90 BlockAttributes.map[20:23] ;
polyEditUV -pu 0.5 -pv 0.5 -a -90 BlockAttributes.map[16:19] BlockAttributes.map[0:3] BlockAttributes.map[8:11];

shaves off a bit of time and is more standalone.

[andy-hosking]

Thanks for your help Jooja. Sorry if my code offends you, but Im taking over from a previous employee in a new job and learning mel script as I go.

I only put up a tiny example. These scripts can sometimes be creating 50,000 materials & 15,000 boxes. Then 50% extra can go from 20 minutes to 30 minutes.

The inches thing was only really introduced because all people using it need to be working in the same units, and I thought it made sense to be working in inches if that's what 1 unit was in the original .csv file.

[joojaa]

Sorry if my code offends yo

it dont offend me, but see 50-70% of something thats barely measureable is a big deal but yes

I only put up a tiny example.

Yeah tahst what i expected. this is why i said if thsi is your code. Since you claimed otherwise allready

Some tips:

dont make 50,000 materials make one material and 50,000 attributes connected via a switch to thet one material. Or make the datavalues pour in using per face colors. its way more productive, manageable and inuitive.

Alternate method dont duplicate 15000 cubes, make a particle instancer that proxies the bives for you on screen and dump the actual data into a ready made mi file. Thisway your rendertimes and creation times come coaring down. Theres no reason for this to take more than 2 minutes.

Avoid the shape ranames, ist just purely wastefull in terms of speed.

use a for loop! makes it easeirfor you to change and manage.

but Im taking over from a previous employee in a new job and learning mel script as I go.

Sucks doens't it.

[joojaa]

Some structural chnages:

why do you do the same thing over and over again?

select -r Base_0_7223;
rotate -r -os 0 0 0

is ateh same thing as manipulating:

select -r Base_0_7223_ATR ;

Also dont sue select like this ist just slows you down by 50% atleast.

Ainstad pass teh commands selection lists in forms of names for example instead of

select -r BlockAttributes ;
duplicate -rr -renameChildren BlockAttributes; scale -r 48 18 4.75; rotate -r 0 0 0; move -r  24 -6 2.375;
rename |BlockAttributes1|Block1 "Base_0_7223" ;
rename |BlockAttributes1 "Base_0_7223_ATR" ;

do:

$this=duplicate -rr -n "Base\_0\_7223\_ATR" BlockAttributes;
xform -r -s 48 18 4.75 -ro 0 0 0 -t 24 -6 2.375 $this;

now to do the thing better proper youd do:

//Product Number -Base_0_7223
//Product Type -BASE
$this=duplicate-n "Base\_0\_7223\_ATR" BlockAttributes;
xform -r -s 48 18 4.75 -ro 0 0 0 -t 24 -6 2.375  $this;
makeIdentity -apply true -t 1 -r 1 -s 1 -n 0 $this;
xform -rp 0 0 0 -sp 0 0 0 $this;
sets -e -forceElement Fixture_ShelfGroup $this;
xform -r -os -ro 0 0 0 -t 2883.053563 1559.536442 0;
parent $this Fix_70701016_PLN_Section4_7222;

im omitting reneaming teh damn child, itt just slows things down unnecceserily. But you could do that. Now since you repeat this a lot you shoudl functionize it.

proc makeAPlacedBlock(string $name, string $sgName,
                      float $preXform[], float $postXform[])
{
  $this=`duplicate-n $name BlockAttributes`;
  xform -r -s $preXform[0] $preXform[1] $preXform[2]
           -ro $preXform[3] $preXform[4] $preXform[5]
           -t $preXform[6] $preXform[7] $preXform[8]  $this;
  makeIdentity -apply true -t 1 -r 1 -s 1 -n 0 $this;
  xform -rp 0 0 0 -sp 0 0 0 $this;
  sets -e -forceElement $sgName $this;
  xform -r -os -ro $postXform[0] $postXform[1] $postXform[2] -t $postXform[3] $postXform[4] $postXform[5];
}

Now you can do:

//Product Number -Fix_70701016_PLN_Section4_7222
//Product Type -FIXTURE

makeAPlacedBlock("Fix_70701016_PLN_Section4_7222","Fixture_ShelfGroup"
[8, 22, 0.001, 0, 0, 0, 24, -11, 0.0005],[0, 0, 0, 2883.053563, 1559.536442, 0]);

//Product Number -Base_0_7223
//Product Type -BASE

makeAPlacedBlock("Base_0_7223","Fixture_BaseGroup"
[48, 18, 4.75, 0, 0, 0, 24, -6, 2.375],[0, 0, 0, 2883.053563, 1559.536442 ,0]);
parent Base_0_7223 Fix_70701016_PLN_Section4_7222;

Then put this in a foor loop and so on. should get saner to work with.

yada yada.

[andy-hosking]

That's all very useful. Thanks a lot for that!

dont make 50,000 materials make one material and 50,000 attributes connected via a switch to thet one material. Or make the datavalues pour in using per face colors. its way more productive, manageable and inuitive.

Can you give any other info to kick me in the right direction with cutting the materials down. Either switch or datavalues into per face colors?