Basic Mel script for position

[patrick-geoffroy]

Hi there, 

I have a question that I'm sure you guys can answer  in a blink of an eye.
I know nothing about scripting so a little help would be much appreciated. 

I need to get a text file in which I get the X Y Z position of an object, for every frame of an animation. I came across this script over the net which is fine for one frame:

for ($item in ls -sl){
$temp=xform -q -t -ws $item;
print ($temp[0]+" "+$temp[1]+" "+$temp[2]+"n");};

Could someone help me modify it so it will export as a text file (actually I would prefer it to have the extension .wf) for as many frames I need? Also, how could we add the rotation after the position?

I need a very simple text file with 6 columns and no header. Fist 3 are position then rotation. Each frame on a line with no separation, or comma.

Thanks in advance.
Patrick

[nowayfra]

This below should do the trick but ithink you will end up with having more information inside a line, for example the frame number as appendix.
//edit: edited your code you deleted some seconds ago

global proc mhFileOut()
{

global string $curObjectNodeType;
global string $outDirTxt;
global string $lvlOutList;
global string $lvlFileName;
global string $lvlFileName;
global string $lvlPrefix;

    if (window -exists LvlOutWin)
        {
        deleteUI -window LvlOutWin;
        }

    string $lvlWindow =window -title "File Exporter v2.1" -width 200 -height 345
                    -sizeable 1 -tlc 150 150 LvlOutWin;

    string $form = formLayout;

    string $dirOutBut = button -width 150 -height 30 -label "Choose Output Directory" -c "getDestDirectory";
    string $outTxt = text -label "Output Directory:";
    string $outDirTxt = text -label "";
    string $nameTxt = text -label "Name:";
//    string $lvlFileName = textField;
    string $controls[] = {(string(textField))};
    string $expLVL = button -label "Export File" -height 34 -c "expLvlFile";
    string $startText = text -l "frame start: ";
    string $endText = text -l "frame end: ";
    $controls[1] = intField;
    $controls[2] = intField;

    formLayout -edit
        -af $dirOutBut "left" 2
        -af $dirOutBut "right" 2
        -af $dirOutBut "top" 5

        -af $outTxt "left" 2
        -ac $outTxt "top" 2 $dirOutBut

        -ac $outDirTxt "top" 2 $outTxt
        -af $outDirTxt "left" 2

        -af $nameTxt "left" 2
        -ac $nameTxt "top" 2 $outDirTxt

        -ac $controls[0] "left" 2 $nameTxt
        -ac $controls[0] "top" 2 $outDirTxt
        -af $controls[0] "right" 2

        -af $expLVL "left" 2
        -af $expLVL "right" 2
        -af $expLVL "bottom" 2

    -ac $startText "top" 2 $controls[0]
    -af $startText "left" 2

    -ac $controls[1] "top" 2 $controls[0]
    -ac $controls[1] "left" 2 $startText

    -ac $endText "top" 2 $controls[0]
    -ac $endText "left" 4 $controls[1]

    -ac $controls[2] "top" 2 $controls[0]
    -ac $controls[2] "left" 4 $endText

        -af $expLVL "left" 2
        -af $expLVL "right" 2
        -ac $expLVL "top" 4 $startText

    $form;
    button -edit -command ("expLvlFile  {\"" + stringArrayToString $controls "\",\"" + "\"}") $expLVL;

showWindow $lvlWindow;

}

////////////////////////////////////
//   Get Destination Directory    //
////////////////////////////////////

global proc string getDestDirectory()
{

    global string $targetDirectory;
    string $targetNtDirectory;
    string $targetPathElements[];
    int $i, $pathElementsCount;
    fileBrowser "getTargetDirectory" "Choose Destination Directory" "directory" 4;
    tokenize($targetDirectory,"/",$targetPathElements);
    $pathElementsCount=size($targetPathElements);
    for ($i=0;$i<$pathElementsCount;$i++)
    $targetNtDirectory=$targetNtDirectory+$targetPathElements[$i]+"\";
    return $targetNtDirectory;
}

///////////////////////////////
//   Get Target Directory    //
///////////////////////////////

global proc getTargetDirectory ( string $directory , string $type)
{
    global string $outDirTxt;
    global string $targetDirectory;
    $targetDirectory=$directory + "/";
    text -edit -label (""+$targetDirectory+"") $outDirTxt;
}

///////////////////////////
// Export the Level File //
///////////////////////////

global proc expLvlFile(string $controls[])
{
    global string $curObjNodeType;
    global string $lvlFileName;
    global string $targetDirectory;
    global string $lvlOutList;
    global string $lvlPrefix;
    //get the name of the file to be created
    string $lvlFileNameTxt = textField -q -tx $controls[0];
    $LvlFile = ($targetDirectory + $lvlFileNameTxt + ".wf");

    int $startFrame = intField -q -v $controls[1];
    int $endFrame = intField -q -v $controls[2];
    string $objects[] = ls -sl;

    $fileId = fopen $LvlFile "w";
    for($i=$startFrame;$i<=$endFrame;$i++){
        currentTime $i;
        for($obj in $objects){
            float $t[] = xform -q -worldSpace -translation $obj;
            float $r[] = xform -q -worldSpace -rotation $obj;

            fprint $fileId($obj + " " + $t[0] + " " + $t[1] + " " + $t[2] + " " + $r[0] + " " + $r[1] + " " + $r[2] + "\n");
        };
    };
    fclose $fileId;    
}

[patrick-geoffroy]

Thank you, thank you thank you!

It works great for my needs.

[patrick-geoffroy]

You can see in the script below that I changed the window layout to add more textfields. The commands I added are located between the dot lines.

Basically, I created textfields and later on I try to query the string inside the textfield. Of course it's not working. I was looking at how you did it and you use: 

string $controls[] = {(string(textField))};
...
$controls[1] = intField -width 70 -height 20;   
$controls[2] = intField -width 70 -height 20; 
...
$form;   
button -edit -command ("expLvlFile1  {\"" + stringArrayToString $controls "\",\"" + "\"}") $expLVL;
...
global proc expLvlFile1(string $controls[]){     
global string $targetDirectory1;        
 //get the name of the file to be created   
string $lvlFileName1Txt1 = textField -q -tx $controls[0]; 
...

What did you do? Can you explain your logic? Is it an array of some sort?
Why is it that in my case, I can't retrieve the textfield info later on,  because it tells me the variables are not declared?
I have tried making all the strings global but with no success. Sorry for being such a beginner but I'm so new to scripting.

global proc Pos_crt()
{
 
    if (`window -exists LvlOutWin`)
        {
        deleteUI -window LvlOutWin;
        }
 
    string $lvlWindow =`window -title "Position .crt file" -width 400 -height 600 
                    -sizeable 1 -tlc 400 600 LvlOutWin`;
 
 
 
    string $form = `formLayout`;
 
    string $dirOutBut = `button -width 150 -height 30 -label "Choose Output Directory" -c "getDestDirectory"`;
    string $outTxt = `text -label "Output Directory:"`;
    string $outDirTxt1 = `text -label ""`;
    string $nameTxt = `text -label "Name:"`;
//    string $lvlFileName1 = `textField`;
    string $controls[] = {(string(`textField`))};
    string $expLVL = `button -label "Export File" -height 34 -c "expLvlFile"`;
    string $startText = `text -l "Frame Start: "`;
    string $endText = `text -l "Frame End: "`;
    $controls[1] = `intField -width 70 -height 20`;
    $controls[2] = `intField -width 70 -height 20`;
 
    ----------------------------------------------------------
    string $titleText = `text -label "Title:  "`;
    string $titleInput1  = `textField`;
 
    string $nameText = `text -label "Name:  "`;
    string $nameInput1  = `textField`;
 
    string $unitText = `text -label "Unit:  "`;
    string $unitInput1  = `textField -width 50 -height 20`;
 
    string $sourceText = `text -label "Source:  "`;
    string $sourceInput1  = `textField -width 160 -height 20`;
 
    string $authorText = `text -label "Author:  "`;
    string $authorInput1  = `textField -width 160 -height 20`;
 
    string $dateText = `text -label "Date:  "`;
    string $dateInput1  = `textField -width 100 -height 20`;
    string $dateexample = `text -label "example: 2012/01/01"`;
 
    string $hourText = `text -label "Time:  "`;
    string $hourInput1  = `textField -width 100 -height 20`;
    string $hourexample = `text -label "example: 18:00:00"`;
    ----------------------------------------------------------
 
    formLayout -edit
     -af $dirOutBut "left" 2
        -af $dirOutBut "right" 2
        -af $dirOutBut "top" 5
 
        -af $outTxt "left" 2
        -ac $outTxt "top" 2 $dirOutBut
 
        -ac $outDirTxt1 "top" 2 $outTxt
        -af $outDirTxt1 "left" 2
 
        -af $nameTxt "left" 2
        -ac $nameTxt "top" 2 $outDirTxt1
 
        -ac $controls[0] "left" 2 $nameTxt
        -ac $controls[0] "top" 2 $outDirTxt1
        -af $controls[0] "right" 2
 
        -af $expLVL "left" 2
        -af $expLVL "right" 2
        -ac $expLVL "top" 2 $controls[1]
 
    -ac $startText "top" 15 $controls[0]
    -af $startText "left" 2
 
    -ac $controls[1] "top" 12 $controls[0]
    -ac $controls[1] "left" 2 $startText
 
    -ac $endText "top" 15 $controls[0]
    -ac $endText "left" 4 $controls[1]
 
    -ac $controls[2] "top" 12 $controls[0]
    -ac $controls[2] "left" 4 $endText
 
 
	-af $titleText "left" 2
	-ac $titleText "top" 20 $startText
 
 
	-af $titleInput1 "left" 50
	-af $titleInput1 "right" 2 
 	-ac $titleInput1 "top" 20 $startText
 
	-af $nameText "left" 2
	-ac $nameText "top" 12 $titleText
 
	-af $nameInput1 "left" 50
	-af $nameInput1 "right" 2 
 	-ac $nameInput1 "top" 10 $titleText
 
	-af $unitText "left" 2
	-ac $unitText "top" 10 $nameText
 
	-af $unitInput1 "left" 50	
 	-ac $unitInput1 "top" 10 $nameText
 
	-af $sourceText "left" 2
	-ac $sourceText "top" 12 $unitText
 
	-af $sourceInput1 "left" 50	
 	-ac $sourceInput1 "top" 10 $unitText
 
	-af $authorText "left" 2
	-ac $authorText "top" 12 $sourceText 
 
	-af $authorInput1 "left" 50	
 	-ac $authorInput1 "top" 10 $sourceText 
 
	-af $dateText "left" 2
	-ac $dateText "top" 12 $authorText 
 
	-af $dateInput1 "left" 50	
 	-ac $dateInput1 "top" 10 $authorText
 
	-af $dateexample "left" 160	
 	-ac $dateexample "top" 12 $authorText
 
	-af $hourText "left" 2
	-ac $hourText "top" 12 $dateText 
 
	-af $hourInput1 "left" 50	
 	-ac $hourInput1 "top" 10 $dateText
 
	-af $hourexample "left" 160	
 	-ac $hourexample "top" 12 $dateText
 
 
 	-af $expLVL "left" 2
       -af $expLVL "right" 2
       -ac $expLVL "top" 20 $hourText
 
 
 
 
 
    $form;
    button -edit -command ("expLvlFile1  {\"" + `stringArrayToString $controls "\",\""` + "\"}") $expLVL;
 
 
 
showWindow $lvlWindow;
 
}
 
 
 
 
////////////////////////////////////
//   Get Destination Directory    //
////////////////////////////////////
 
global proc string getDestDirectory() 
{ 
 
    global string $targetDirectory1; 
    string $targetNtDirectory; 
    string $targetPathElements[]; 
    int $i, $pathElementsCount; 
    fileBrowser "getTargetDirectory" "Choose Destination Directory" "directory" 4; 
    tokenize($targetDirectory1,"/",$targetPathElements); 
    $pathElementsCount=size($targetPathElements); 
    for ($i=0;$i<$pathElementsCount;$i++) 
    $targetNtDirectory=$targetNtDirectory+$targetPathElements[$i]+"\\"; 
    return $targetNtDirectory; 
} 
 
///////////////////////////////
//   Get Target Directory    //
///////////////////////////////
 
global proc getTargetDirectory ( string $directory , string $type) 
{ 
    global string $outDirTxt1;
    global string $targetDirectory1; 
    $targetDirectory1=$directory + "/"; 
    text -edit -label (""+$targetDirectory1+"") $outDirTxt1;
}
 
///////////////////////////
// Export the Level File //
///////////////////////////
 
global proc expLvlFile1(string $controls[])
{
 
    global string $targetDirectory1; 
 
 
 
 //get the name of the file to be created
    string $lvlFileName1Txt1 = `textField -q -tx $controls[0]`;
    $LvlFile1 = ($targetDirectory1 + $lvlFileName1Txt1 + ".crt");
 
    $fileId1 = `fopen $LvlFile1 "w"`;
 
  ----------------------------------------------------------------  
 
    string $titlevar = `textField -q -tx $titleInput1`;
   string $namevar  = `textField -q -tx $nameInput1`;
   string $unitvar  = `textField -q -tx $unitInput1`;
   string $sourcevar  = `textField -q -tx $sourceInput1`;
   string $authorvar  = `textField -q -tx $authorInput1`;
   string $datevar  = `textField -q -tx $dateInput1`;
   string $hourvar  = `textField -q -tx $timeInput1`;
 
 
 
   fprint  $fileId1("[HEADER]" + "\n" + "\n");
   fprint  $fileId1("Title:" + " " + $titlevar + "\n" );
   fprint  $fileId1("Name:" + " " + $namevar + "\n" );
   fprint  $fileId1("Class:" + " " + "PATH0" + "\n" );
   fprint  $fileId1("Type0:" + " " + "Position" + "\n" );
   fprint  $fileId1("Unit:" + " " + $unitvar + "\n" );
   fprint  $fileId1("Source:" + " " + $sourcevar + "\n" );
   fprint  $fileId1("Author:" + " " + $authorvar + "\n" + "\n" );
   fprint  $fileId1("[Data]" + "\n" + "\n"); 
   fprint  $fileId1($datevar + "," + "    " +  $hourvar  + "\n" );
   fprint  $fileId1("Interval=0.041046" + "\n" + "\n" );
 
  ---------------------------------------------------------------  
 
 
  int $startFrame = `intField -q -v $controls[1]`;
    int $endFrame = `intField -q -v $controls[2]`;
    string $objects[] = `ls -sl`;
 
 
    for($i=$startFrame;$i<=$endFrame;$i++){
        currentTime $i;
        for($obj in $objects){
            float $t[] = `xform -q -worldSpace -translation $obj`;
 
            fprint $fileId1($t[0] + " " + $t[1] + " " + $t[2]  + "\n");
        };
    };
    fclose $fileId1;    
}

 

[nowayfra]

The simple logic behind: it puts the names of the control fields (textField, intFields) into an array and hand it over to the main procedure, the values are beeing queried there.

occupy the string array at declaration with a single element, the name of a text field. You need to cast the command result of textFieldas string to not let the interpreter nag because of absent scalar value.

string $controls[] = {(string(`textField`))};

...
put the other controls names in the array. Once the array $controls[] is declared as string array, we do not need to cast as string here.

$controls[1] = `intField -width 70 -height 20`;
$controls[2] = `intField -width 70 -height 20`;

...

button -edit -command ("expLvlFile1  {\"" + `stringArrayToString $controls "\",\""` + "\"}") $expLVL;

just a method to get the variables from the UI into the procedure "expLvlFile1(string $controls[])". We do the queries of the UI controls there, so we first have to put the control field names through the call pipe into the procedure. If $controls would be declared globally, we could name the command:

-edit -command("expLvlFile1 $controls")

But since globals are evil (joking, they are usefull at certain circumstances, all you need to keep in mind is that thousands of factory scripts rely at globally declared variables and so you better create some really unique names for your variables to avoid trouble) we store the name of the controls directly inside the command string for the button while the UI is built (the local string $controls counts while building the UI, after its built the variable is gone and the control field names cant be retrived anymore). So the command string printed out would look like this:

expLvlFile1 {"nameOfControl1","nameOfControl2","nameOfControl3"}

To get this string as result, the declaration of this string needs to look like:

-edit -command("expLvlFile1 {\"nameOfControl1\",\"nameOfControl2\",\"nameOfControl3\"}")

Besides: putting " into a string needs the escape character \ prepended.
And thats exactly whats going on here:

-edit -command("expLvlFile1  {\"" + `stringArrayToString $controls "\",\""` + "\"}")

Look into the docs for stringArrayToString, it flattens an array into a single string using a separator, the separator in this case is "," and written as string it gets "\",\""

Handing over an array lets you easily create new controls, all you have to do is put the controls names into the string array. No need to change the command string, and no need to change the procedures prototype. For more essentially procedures (some you will probably call from inside an other procedure) it makes more sense to put a proc in between that queries the controls and calls the main procedure with its plain values, so you dont need to hand over control field names. For big interfaces whit lots of controls resulting into different variable types it works good this way while developing: UI controls into string array, proc between to query and call the main proc, main proc with this prototype: mainProc(string $stringValues[], float $floatValues[], int $intValues[]) Disadvantage here is to keep oversight of what the different indices represent.

Finally, if you want to extend your UI with controls you need to query in the main proc, do:
in UI proc put the new contols into $controls like

$controls[3] = `checkBox -l "use objectSpace" -value 1`;

in main proc query:

int $useObjectSpace = `checkBox -q -value $controls[3]`;

[patrick-geoffroy]

Wow, awesome! 

Now let me digest this...

I'll surely be back for few more questions.

Thank you again