How to SELECT polygon objects where faces - less than x number?

[forester]

Does anyone know what the MEL code would be for this, if it is possible?

Thanks,
Pam

[davus]

int    $polyLimit = 300;//Change this number for threshhold

select -cl;
string $sel[] = ls -type "mesh";
string $polySel[];
clear  $polySel;

//Loop through all polygon objects
for($i=0;$i<size($sel);$i++){
    int $polyCount[] = `polyEvaluate -f $sel[$i]`;
    if($polyCount[0] < $polyLimit){$polySel[size($polySel)] = $sel[$i];}
}

//Select objects
select -r $polySel;

[davus]

This is better, it selects the transforms instead of the shapeNodes:

int    $polyLimit = 300;//Change this number for threshhold

select -cl;
string $sel[] = ls -type "mesh";
string $polySel[];
clear  $polySel;

//Loop through all polygon objects
for($i=0;$i<size($sel);$i++){
    int $polyCount[] = `polyEvaluate -f $sel[$i]`;
    if($polyCount[0] < $polyLimit){
        string $transform[] = `listRelatives -p $sel[$i]`;
        $polySel[size($polySel)] = $transform[0];
    }
}   

//Select objects
select -r $polySel;

[forester]

Thank you very much!  I'll give this a try.

That is REALLY COOL!   It works great!  Wonderful !!!!!!!!!

Thank you again, very, very much!!!!!

If you'll "friend me" here, and let me ask for your e-mail addy, I would like to send you a small fee via Paypal to express my thanks for the huge amount of time you are saving me in my work.

Thanks again!